Meta-Nixie Clock

I recently caught Matt Mets’ post on hacking a digital photo frame into a clock by generating a static image for each minute of the day, and then automating the action of advancing the image once per minute. This allows for any number of interesting clocks to be made with suggestions ranging from a written-word clock (as Matt’s project did) to photographing various clocks at each minute of the day to photographs of people miming clock hands. I happened to show this post to my husband and he absolutely loved the idea and wanted one for his desk at work. I immediately realized that I had found the perfect Christmas gift for him!

Next up was marking the pattern of brass tacks I would be applying. I was going for the classic zig-zag offset pattern one might find on an old leather club chair, so I marked off a grid with a fine-tipped sharpie and went to work with the tacks and hammer. (Just before tacking, I made a quick pass over the frame with some dark brown shoe polish to create an aged look)

//Thanks to Matt Mets for the initial version of this, to which the code below
//bears only a passing resemblance…
//To use this sketch, you will need an image of all 10 digits (all equally
//sized and closely cropped) as well as a colon image and a blank spacer image.
//These must be in the Data directory in the sketch's directory

// Set these to match the resolution of your frame
int imageWidth = 480;
int imageHeight = 234;

//This array holds the names of the digit images
String[] imagenames =
  { "zero.jpg", "one.jpg", "two.jpg", "three.jpg", "four.jpg", "five.jpg",
    "six.jpg", "seven.jpg", "eight.jpg", "nine.jpg" };
String imageName = new String();

//This will hold the image objects for each digit
PImage[] images = new PImage[10];
//This image will be added to the front and back of the clock
//image to pad it out to the size of the frame as defined at the top
PImage spacerImage;
//The colon image used to separate the hours from the minutes
PImage colonImage; 

//The width of each digit. Generally you will take the width of your frame
//and divide by 5. (4 digits plus the colon) Since the colon will be much
//narrower, you will want to split the extra into the front and back
//padding. My frame is 480px which gives me 5 digits of 96px. I chose to
//make my colon 26px wide, leaving 70px. I then divided that in two to
//arrive at a 35px spacer front and back

int digitwidth = 96;
int colonwidth = 26;
int spacerwidth = 35;

int myInt, count=0;

void setup() {
  //Populate the array of images using the image name array above
for (myInt = 0; myInt<10; myInt++){
 images[myInt] = loadImage(imagenames[myInt]); 

}

//load the non-digit images
  spacerImage = loadImage("spacer.jpg");
  colonImage = loadImage("dot.jpg");
  imageMode(CORNER);

// Set Processing's screen to the size of the frame so the images won't
//be scaled by the frame, get blocky, take too long to load, etc. and
//give us all black bg/fill/stroke
  size(imageWidth, imageHeight);

//You can use a different background color, but if your images are
//sized correctly, you shouldn't see it anyway
  background(0);
  stroke(0);
  fill(0);

//Starts at 1:00 and works through to 12:59 - your clock will start at
//1:00 instead of 12:00 when first powered up

for( int hours = 1; hours < 13; hours++ ) {
    for( int minutes = 0; minutes < 60; minutes++) {
      // Clear the background by painting over it
      background(0);
      //Draw the first spacer image at the far left
      image(spacerImage,0,0);
      //Draw the colon in the middle
      image(colonImage,spacerwidth+(digitwidth*2),0);
      //Draw the second spacer at the far right
      image(spacerImage,spacerwidth+colonwidth+(digitwidth*4),0);

      //divide hours by 10 to get first digit, 0 or 1
      image(images[hours/10],spacerwidth,0);
      //mod hours by 10 to get second digit, 0-9
      image(images[hours%10],spacerwidth+digitwidth,0);
      //divide minutes by 10 to get first digit, 0-6
      image(images[minutes/10], spacerwidth+colonwidth+(digitwidth*2), 0);
      //mod minutes by 10 to get second digit, 0-9
      image(images[minutes%10], spacerwidth+colonwidth+(digitwidth*3), 0); 

// Write out an image file. My frame handleded >200 images/folder fine, so
//I removed the subfolder code, but you can enable it if you need.
//Note the ugly code that pads zeros into the imageName string and which
//should be done a different way with string formatting, but, hey, it was
//very early when I wrote this.

      imageName="";
      if(count < 1000){
          imageName="0";
          if(count < 100){
            imageName = "00";
            if (count < 10){
              imageName = "000";
            }
          }
      }

//Use this line if you need to break the images into 200/folder
//      save(count/200 + "/" + imageName + count++ + ".jpg"); 

//This line saves the image as a jpg
      save( "img/" + imageName + count++ + ".jpg");
    }
  }
}

So, putting it all together and turning it on, I ended up with a very nice meta-Nixie clock as a great gift for my husband Cameron – who absolutely loved it, by the way!

• Twitter

  • No public Twitter messages.

• Pages

  • About W

• Links

  • Artisan's Asylum is my home
  • David Nunez and I worked together
  • Lance Olsen inspires me
  • Matt Borgatti makes cool things

• Archives

  • April 2012
  • March 2012
  • February 2012
  • September 2011
  • August 2011
  • July 2011
  • April 2010
  • January 2010
  • December 2009
  • August 2009
  • June 2009
  • May 2009
  • April 2009
  • March 2009
  • February 2009
  • January 2009
• Search for: